【バッチファイル】FTPサーバーへファイルを送信する

前提

バッチファイルへファイルを送信するために、バッチファイル内で以下の3つを実施します。

コード

ここでは例として
　・デスクトップ配下のファイル「test01.txt」を
　・FTPコマンドを使用して、FTPサーバーへ送信
します。

@echo off

rem FTPサーバー名
set ftpServerName=ftpServerName
rem ユーザー名
set userName=loginUser
rem パスワード
set password=password
rem FTPコマンドファイル
set ftpCmdFile=C:\Users\user\Desktop\ftp_cmd.txt
rem 送信ファイル
set sendFile=C:\Users\user\Desktop\test01.txt
rem FTPサーバー側のフォルダ
set serverFolderPath=/temp/

rem FTPコマンドファイルが存在したら削除
if exist %ftpCmdFile% (
	rem ファイルを削除
	del /f %ftpCmdFile%
	echo FTPコマンドファイルを削除しました。
	echo.
)

rem -----------------------------------------
rem FTPコマンドファイル作成
rem -----------------------------------------
rem FTPサーバー
echo open %ftpServerName%>> %ftpCmdFile%
rem ユーザー名
echo %userName%>> %ftpCmdFile%
rem パスワード
echo %password%>> %ftpCmdFile%
rem 転送モード
echo BINARY>> %ftpCmdFile%
rem FTPサーバー側のフォルダ移動
echo cd %serverFolderPath%>> %ftpCmdFile%
rem 送信コマンド
echo put %sendFile%>> %ftpCmdFile%
rem FTPコマンドファイルClose
echo bye>> %ftpCmdFile%

rem -----------------------------------------
rem FTPコマンド実行
rem -----------------------------------------
ftp -i -s:%ftpCmdFile%

rem -----------------------------------------
rem FTPコマンドファイル削除
rem -----------------------------------------
del /f %ftpCmdFile%

echo.

pause
exit

上記で作成される「FTPコマンドファイル」は以下になります。
※上記に記載している通り、このファイルは実行後に削除しています。

open ftpServerName
loginUser
password
cd /temp/
BINARY
put C:\Users\user\Desktop\test01.txt
bye

実行結果

FTPサーバーへファイルを送信できました。
※デスクトップ配下のファイル「test01.txt」をFTPサーバー側の「/temp/」配下へ送信できました。

参考①

FTPサーバーからファイルを受信(取得)することもできます。

詳細は以下の記事をご確認ください。

参考②

上記で使用した以下の詳細は、公式サイトをご確認ください。

●ftpコマンド

●FTPのopenコマンド(FTPへ接続するコマンド)

●FTPのputコマンド(ファイルを送信するコマンド)

●FTPのbyeコマンド(FTPを切断するコマンド)